4 Types of Development Type Attributes

Development Types have attributes, such as housing density, average household income, and children per household.  These unique attributes are the result of the mix of different buildings, the roadway characteristics defined and the open space assumptions provided by the user.  

The attributes of Development Types in Envision Tomorrow can be devided into 4 basic classifications.  

  • Averages: variables that are fixed, aspatial and do not increase based on how much area the user paints.  Examples include, average household size or average household income.  
  • Per Acre: variables that can increase the more acres are painted by the user.  Examples include housing units per acre.  There are two types of per acre variables
    • From building count to development type per acre: these variables are weighted averages of the building-level count attributes aggregated to the Development Type level, such as number of floors.  The weight is the user-defined mix of building types.
    • From building per acre to development type per acre: these variables are simply weighted averages of building-level per acre values, such as building-level housing units per acre.  The weight is the user-defined mix of building types.
  • Per a Second Attribute: variables that depend on a second Development Type variable for calculation.  Examples include 


Formulas for Aggregating Building-level Attributes to Development Types

The format for each of these equation types are below:


=SUMPRODUCT(TRANSPOSE(B_Variable),'Dev Type Building Mix'!X6:BU6)

Per Acre (from building count to Dev Type per acre)

=IFERROR(SUMPRODUCT(TRANSPOSE(B_Variable),'Dev Type Building Mix'!$X6:$BU6,TRANSPOSE(IFERROR(43560/B_Lot_Size,0))),0)

Per Acre (from building per acre to Dev Type per acre)

=IFERROR(SUMPRODUCT(TRANSPOSE(B_Variable),'Dev Type Building Mix'!$X6:$BU6),0)

Per Another Attribute

=IFERROR(SUMPRODUCT(TRANSPOSE(B_Variable), TRANSPOSE(B_Pivot_Variable),'Dev Type Building Mix'!$X6:$BU6)/SUMPRODUCT(TRANSPOSE(B_Pivot_Variable),'Dev Type Building Mix'!$X6:$BU6),0)

Example: Average Household Size

=IFERROR(SUMPRODUCT(TRANSPOSE(B_HH_Size), TRANSPOSE(B_HH_Acre),'Dev Type Building Mix'!$X6:$BU6)/SUMPRODUCT(TRANSPOSE(B_HH_Acre),'Dev Type Building Mix'!$X6:$BU6),0)


Additional Information

Building Mix Weight

For Line 1 = 'Dev Type Building Mix'!X6:BU6

Note: When copied down, the row numbers increase.

Array Formulas

Unless otherwise noted, all formulas are array formulas.